Ansys模拟水结冰的热分析过程

Ansys模拟水结冰的热分析过程
一、问题描述：
对一茶杯水的结冰过程进行分析，水和茶杯的初始温度为0℃，环境温度为-10℃，杯子侧面和顶面的对流换热系数为12.5W/m^2·℃，杯子放在桌面上，假设桌面可以对杯子底面提供-10℃的温度载荷。

计算3000s之后的温度分布。

模型如下：
茶杯底面外径54.41mm，内径50mm，高度85mm，顶面内径60mm，抽壳厚度为5mm（内部水的高度80mm）。

分析采用SI单位制，水的材料属性如下：
导热率：0.6
密度：1000
比热容：4200
焓值：
温度℃-10 -1 0 10
焓J/m^3 0 37.8e6 79.8e6 121.8e6
茶杯采用铁的材料属性：
导热率：70
密度：7833
比热容：448
二、问题分析：
本例采用70热单元进行分析，由于对称性，采用1/4模型进行建模分析。

由于包含相变分析，因此水的焓值是必要的。

假设温度0℃的水结成0℃的冰需要放出42000J/kg·℃的热量，通过定义焓值来实现。

假设温度区间长度为1℃，因此温度低于-1℃，表示水已结成冰。

本例通过apdl进行分析，方便输入及调试。

三、分析步骤:
1、定义工程名及标题
fini
/cle ！清除数据库
/filname.shuijiebing,1 ！此处设置工作名
/title,lovz ！此处设置标题
*afun deg !定义角度为度
2、进入前处理，定义单元及材料属性
/prep7 ！进入前处理模块
et,1,70 ！定义70单元
mp,kxx,1,0.6 ！设置材料属性
mp,c,1,4200
mp,dens,1,1000
mptemp,1,-10,-1,0,10
mpdata,enth,1,1,0,37.8e6,79.8e6,121.8e6 ！焓值定义mp,kxx,2,70
mp,dens,2,7833
mp,c,2,448
这里定义1号材料为水，2号材料为茶杯
3、定义参数
r1=50e-3
r2=60e-3
r3=54.41e-3
r4=65e-3
h1=80e-3
h2=85e-3
4、建模
wprot,,-90 ！旋转工作平面
/pnum,volu,1 ！打开体积显示
/view,1,1,1,1 ！Iso视角
cone,r1,r2,0,h2,0,90 ！建立水的1/4圆台模型
cone,r3,r4,0,h2,0,90 ！建立茶杯轮廓模型wpoff,,,h2-h1 ！移动工作平面
vsbw,all ！用工作平面切割体，方便扫掠划分网格vovlap,all ！对体进行叠分操作
vglue,all ！对体进行粘接操作
numcmp,all ！压缩所有编号
wpcsys,-1,0 ！工作平面回归原点
/replot ！重新显示
5、对体赋予材料属性
vsel,,,,1,3 ！体积1到3
vatt,2,,1 ！赋予2号材料属性
vsel,,,,4 ！体积4
vatt,1,,1 ！赋予1号材料属性
Allsel ！选择所有
/pnum,mat,1 ！打开材料编号显示
Vplot ！模型显示
模型显示如上，紫色部分为茶杯，材料属性2 6、分网
esize,2.5e-3 ！单元尺寸2.5e-3
vsweep,all ！扫掠划分
网格划分如上，可见网格密度还是可以接受的。

7、进行求解设置
/sol ！进入求解模块
toff,273 ！设置温度偏移
antype,4 ！瞬态分析
outres,all,all ！输出设置，选择输出所有
tunif,0 ！设置初始温度
timint,on ！打开时间积分
time,3000 ！设置时间
deltim,30,30,100 ！设置子载荷步时间，下限30s，上限100s autots,on ！打开自动时间步长
kbc,1 ！阶跃载荷
初始温度是必须设置的，也可以先关闭时间积分，对整体施加0℃的温度载荷，进行稳态分析，随后打开时间积分，进行瞬态分析。

8、施加载荷
用/pnum,area,1 打开面显示，再用APLOT，确定要施加载荷的面的编号。

随后施加载荷
asel,,,,16,17
asel,a,,,2
asel,a,,,7 ！选择对流边界的面编号
sfa,all,,conv,12.5,-10 ！施加对流
asel,,,,1
asel,a,,,3 ！选择茶杯底面
nsla,s,1 ！选择底面上的全部节点
d,all,temp,-10 ！施加温度载荷
Allsel
这里会提示一个载荷已经被施加的警告提示，确认施加载荷无误，不用管它，继续。

9、求解
Solve
大约进行约2分钟即可求解完成，会显示收敛曲线。

10、后处理
/post1 ！进入后处理模块
set,last ！选择最后一个载荷步
plnsol,temp ！显示温度场分布
✧如上图所示，即为茶杯和水在3000s时的温度分布。

从中可以看出，除了红色部分的水未凝结之外，其余的水已经凝结。

✧仅对水的温度场进行处理，手动设置温度显示范围，可以更清楚看出水的凝结情况，如下
esel,s,mat,,1 ！选择1号材料
Eplot ！显示单元
/cval,1,-10,-1,0,0.1 !设置温度显示范围
plnsol,temp
如上图，蓝色部分表示水已凝结为冰，黄色部分为水。

同样可以查看其它时间的温度场分布。

通过set选项中的by pick 子项目选择自己想要查看的子载荷步，然后查看温度。

如：
/cval ！温度显示复位
set,,,,,,,11 ！选择子载荷步11，即time=521
plnsol,temp
另外也可以通过设置选项，查看动画
antime,10,0.5,,1 ！设置动画
/anfile,save,'lovz' ！保存，在ansys工作目录里提取avi格式动画点击ok或输入上述命令后，即可显示动画，会弹出动画控制框，在滚动条调节动画频率，点击close关闭。

11、进入时间历程处理器
对一些节点进行温度-时间显示处理，如下：
/post26
n1=node(0,10e-3,0) ！选择距茶杯底面10mm的水节点
n2=node(0,30e-3,0) ！选择距底面30mm处的节点
csys,5 ！设置y轴的柱坐标系，方便选择节点
n3=node(r1,45,h2/2) ！选择x=r1，y=45°，z=h2/2的节点
csys,0 ！整体笛卡尔坐标
nsol,2,n1,temp,,t1 ！定义节点温度
nsol,3,n2,temp,,t2
nsol,4,n3,temp,,t3
plvar,2,3,4 ！显示温度-时间曲线
12、至此求解完毕。

本例为轴对称模型，可以采用二维55单元进行分析，由于网格可以设置的更为精细合理，可能结果精度更高。

鉴于3维直观性更好，且二维已有分析示例（仅对水做模拟，而忽略了茶杯对其的影响，并对底面施加了绝热条件），因此采用3维70单元分析。

本例对此优化，对茶杯建模，并施加更接近实际的边界条件。

可以看出水结冰的情况很大程度上决定于茶杯的属性及其边界条件。

因此本例对于该种情况的处理更加符合实际情形（实际桌面不可能对茶
杯底部提供恒定的-10温度载荷，但影响应该不大，会减慢茶杯底部水的结冰速度，可对桌面建模，再将对流施加在桌面上，然后进行热分析）。

13、另外如果要做进一步优化，可以进行二维55单元的分析，同时利用单元生死技术模拟水倒入茶杯中的情形，给茶杯设置与周围环境相同的温度，先进行短时间的稳态分析，再进行瞬态分析，可以更好的模拟实际情况。

14、over _lovz
15、。