/com,new model of linjiang cable_stayed bridge,2004.2.09
/prep7
/title, cable_stayed bridge,author is Sunhang
/com,define the keypoints
*set,alfa1,10 !angle of tower upside
*set,alfa2,65 !angle of tower downside
*set,alfa3,79.04594 !angle of tower with bridge surface
*set,y1,55.5 !桥塔顶面到原点的距离
*set,y2,33.5 !桥塔中部的Y轴向长度
*set,pi,3.1415926
*set,x3,y2/tan(alfa2*pi/180) !桥塔中部的X轴向长度
*set,x2,(y1-y2)*tan(alfa1*pi/180) !桥塔上部的X轴向长度
*set,x1,x2+x3 !桥塔的X轴向长度
*set,kp_yy1,0 !定义桥塔上部的索锚固点竖向距离（从塔顶算起）
*set,kp_yy2,2.5185
*set,kp_yy3,3.5788
*set,kp_yy4,4.6469
*set,kp_yy5,5.7248
*set,kp_yy6,6.8151
*set,kp_yy7,7.9211
*set,kp_yy8,9.0479
*set,kp_yy9,10.2027
*set,kp_yy10,11.3965
*set,kp_yy11,12.6470
*set,kp_yy12,13.9848
*set,kp_yy13,15.7143
*set,kp_yy14,17.7041
*set,kp_yy15,22.0000
k,1,-x1,y1,
k,6,-x1+kp_yy2*tan(alfa1*pi/180),y1-kp_yy2
k,8,-x1+kp_yy3*tan(alfa1*pi/180),y1-kp_yy3
k,10,-x1+kp_yy4*tan(alfa1*pi/180),y1-kp_yy4
k,12,-x1+kp_yy5*tan(alfa1*pi/180),y1-kp_yy5
k,14,-x1+kp_yy6*tan(alfa1*pi/180),y1-kp_yy6
k,16,-x1+kp_yy7*tan(alfa1*pi/180),y1-kp_yy7
k,18,-x1+kp_yy8*tan(alfa1*pi/180),y1-kp_yy8
k,20,-x1+kp_yy9*tan(alfa1*pi/180),y1-kp_yy9
k,22,-x1+kp_yy10*tan(alfa1*pi/180),y1-kp_yy10
k,24,-x1+kp_yy11*tan(alfa1*pi/180),y1-kp_yy11
k,26,-x1+kp_yy12*tan(alfa1*pi/180),y1-kp_yy12
k,28,-x1+kp_yy13*tan(alfa1*pi/180),y1-kp_yy13
k,30,-x1+kp_yy14*tan(alfa1*pi/180),y1-kp_yy14
k,38,-x1+kp_yy15*tan(alfa1*pi/180),y1-kp_yy15
kfill,1,6 !在已建关键点内内插关键点
kfill,6,8
kfill,8,10
kfill,10,12
kfill,12,14
kfill,14,16
kfill,16,18
kfill,18,20
kfill,20,22
kfill,22,24
kfill,24,26
kfill,26,28
kfill,28,30
kfill,30,38
*set,kp_numone,38!定义桥塔上部的最后一个关键点号
/com,define and mesh the above part of tower
*dim,BBS,,40
*dim,HHS,,40
*dim,SSS,,40
*dim,IIYYS,,40
*dim,IIZZS,,40
*set,length1,2.9546108
*set,length2,4.9251168
*set,width1,3
*set,width2,5
*set,diff1_length,length2-length1 !桥塔上部两个截面的长度之差（纵桥向）
*set,diff1_width,width2-width1 !桥塔上部两个截面的宽度之差（横桥向）
*dim,yy,,40 !定义桥塔上部的关键点竖向距离数组（从塔顶计算）
*do,i,1,38
*set,yy(i),y1-ky(i)
*set,hhs(i),diff1_length*yy(i)/(y1-y2)+length1
*set,bbs(i),diff1_width*yy(i)/(y1-y2)+width1
SSS(i)=BBS(i)*HHS(i) !按照实心截面
IIZZS(i)=BBS(i)*HHS(i)**3/12
IIyyS(i)=HHS(i)*BBS(i)**3/12
*enddo
*do,i,1,kp_numone-1
et,i,beam44
keyopt,i,9,0
mp,ex,i,3.5e10
mp,prxy,i,0.167
mp,dens,i,2.6e3
mp,alpx,i,1e-05 !定义混凝土的线膨胀系数
r,i,SSs(i),IIZZS(i),IIyyS(i),BBS(i)/2,HHS(i)/2,IIZZS(i)+IIyyS(i)
rmore,SSs(i+1),IIZZS(i+1),IIyyS(i+1),BBS(i+1)/2,HHS(i+1)/2,IIZZS(i
+1)+IIyyS(i+1)
rmore,0,0,0,0,0,0
rmore,0,0,BBS(i)/2,HHS(i)/2,BBS(i+1)/2,HHS(i+1)/2
lsel,u,real,,1,kp_numone
lstr,i,i+1
latt,i,i,i
lesize,all,,,1,,1
lmesh,all,all
allsel,all
*enddo
cm,uptower,elem
*get,emin_ts,elem,0,num,min
*get,emax_ts,elem,0,num,max
allsel
kp_ts=emax_ts-emin_ts+1 !提取出来桥塔上部的关键点数目
/com,createt the kps of tower down
*set,zfirst,1.25 !三个控制点的横桥向坐标
*set,zsecond,7.4839
*set,kp_numtwo,kp_ts+2 !定义桥塔下部的第一个关键点
*set,diff1_elem,67 !桥塔下部的单元数目
*set,kp_numthree,kp_numtwo+diff1_elem !桥塔下部的最后一个关键点
k,kp_numtwo,-y2/tan(alfa2*pi/180),y2 ,-zfirst
k,kp_numthree,,,-zsecond
kfill,kp_numtwo,kp_numthree
*dim,BBX,,200
*dim,HHX,,200
*dim,SSX,,200
*dim,IIYYX,,200
*dim,IIZZX,,200
*set,HHXQ,0.8*sin(alfa2*pi/180) !定义砍掉部分的长度
*set,BBXQ,0.4*sin(alfa3*pi/180)
*set,SSXQ,HHXQ*BBXQ
*dim,IIYYXQ,,200
*dim,IIZZXQ,,200
!*set,w4,2.6875*2 !在桥塔折角处单元的宽度
!*set,w5,4.3682*2 !在坐标原点处单元的宽度
*set,w4,4.5361558
*set,w5,8.1609208
*do,i,1,diff1_elem+1
BBX(i+kp_numone)=2.5*sin(alfa3*3.1415926/180)
HHX(i+kp_numone)=w4+(i-1)*(w5-w4)/67
SSX(i+kp_numone)=BBX(i+kp_numone)*HHX(i+kp_numone)-SSXQ*2
IIYYXQ(i+kp_numone)=HHXQ*BBXQ**3/12+SSXQ*BBX(i+kp_numone)**2/4
IIZZXQ(i+kp_numone)=BBXQ*HHXQ**3/12+SSXQ*HHX(i+kp_numone)**2/4
IIYYX(i+kp_numone)=HHX(i+kp_numone)*BBX(i+kp_numone)**3/12-IIYYXQ(i+kp_numone)*2
IIZZX(i+kp_numone)=BBX(i+kp_numone)*HHX(i+kp_numone)**3/12-IIZZXQ(i+kp_numone)*2
*enddo
*do,i,KP_numone,kp_numone+diff1_elem-1
et,i,beam44
keyopt,i,9,0
mp,ex,i,3.5e10
mp,prxy,i,0.167
mp,dens,i,2600
mp,alpx,i,1e-05 !定义混凝土的线膨胀系数
r,i,SSX(i+1),IIZZX(i+1),IIYYX(i+1),BBX(i+1)/2,HHX(i+1)/2,IIZZX(i+1)+IIYYX(i+1)
rmore,SSX(i+2),IIZZX(i+2),IIYYX(i+2),BBX(i+2)/2,HHX(i+2)/2,IIZZX(i+2)+IIYYX(i+2)
rmore,0,0,0,0,0,0
rmore,0,0,BBX(i+1)/2,HHX(i+1)/2,BBX(i+2)/2,HHX(i+2)/2
*enddo
*do,i,kp_numtwo,kp_numthree-1
lsel,u,real,,1,150
lstr,i,i+1
latt,i-1,i-1,i-1
lesize,all,,,1,,1
lmesh,all
allsel,all
*enddo
esel,u,real,,1,kp_numtwo-2
cm,downtower,elem
allsel,all
cmsel,s,downtower
*get,emin_tx,elem,0,num,min
*get,emax_tx,elem,0,num,max
allsel
kp_tx=emax_tx-emin_tx+1
esel,all,all
cm,tower,elem
lsel,s,real,,kp_numone,kp_numthree-2
lsymm,z,all,,,100
allsel,all
*set,kp_numfour,kp_numone+2*kp_tx+100+1 !主梁的第一个关键点号
!esel,s,ename,,beam44
!tunif,0
!tref,-30
!allsel,all
/com,couple the tower upside and tower down
cerig,node(kx(38),ky(38),kz(38)),node(kx(39),ky(39),kz(39)),all,
cerig,node(kx(38),ky(38),kz(38)),node(kx(139),ky(139),kz(139)),all,
*set,beam_height,1.2725-0.3 !主梁节点即锚固点到原点的距离
!*set,kp_numfour,kp_numone+2*(kp_tx+1)+100+1 !主梁的第一个关键点号
*set,kp_numfour_inc,210 !主梁
的关键点数目-1
*set,kp_numfive,kp_numfour+kp_numfour_inc
k,kp_numfour,,beam_height
k,kp_numfive,105,beam_height
kfill,kp_numfour,kp_numfive
*do,i,1,kp_numfour_inc
lstr,kp_numfour+i-1,kp_numfour+i
*enddo
*set,enum_beam,emax_tx+1
et,enum_beam,beam188
mp,ex,enum_beam,3.5e10
mp,prxy,enum_beam,0.0.167
mp,dens,enum_beam,3038.8 !考虑到二期恒载后的换算密度
mp,alpx,enum_beam,1e-05 !定义混凝土的线膨胀系数
KEYOPT,enum_beam,7,2
keyopt,enum_beam,8,3
keyopt,enum_beam,9,3
SECTYPE,1,BEAM,MESH,sec1
SECOFFSET,user,,-1.40 !截面读入时主梁的平移
SECREAD,'main_beam','SECT',' ',MESH
k,5000,,1000000
lsel,u,real,,1,200
latt,enum_beam,enum_beam,enum_beam,,5000,,1
lesize,all,,,1,,1
lmesh,all
allsel,all
esel,s,ename,,beam188
cm,main_beam,elem
allsel,all
/com,create the cable element
*set,enum_link,enum_beam+1 !拉索的开始单元号
*dim,cable_area,,13 !定义拉索单元的面积数组
*dim,cable_istrain,,13 !定义拉索单元的初始应变数组
*dim,cable_dens,,13
/com,define the angle of all cable
*set,cable_area1,1.668E-03
*set,cable_area2,1.668E-03
*set,cable_area3,2.6410E-03
*set,cable_area4,2.6410E-03
*set,cable_area5,2.6410E-03
*set,cable_area6,2.6410E-03
*set,cable_area7,3.0580E-03
*set,cable_area8,3.0580E-03
*set,cable_area9,3.0580E-03
*set,cable_area10,3.7530E-03
*set,cable_area11,3.7530E-03
*set,cable_area12,3.7530E-03
*set,cable_area13,3.7530E-03
*set,cable_area_back,2.0155E-02
*set,cable_area(1),cable_area1
*set,cable_area(2),cable_area2
*set,cable_area(3),cable_area3
*set,cable_area(4),cable_area4
*set,cable_area(5),cable_area5
*set,cable_area(6),cable_area6
*set,cable_area(7),cable_area7
*set,cable_area(8),cable_area8
*set,cable_area(9),cable_area9
*set,cable_area(10),cable_area10
*set,cable_area(11),cable_area11
*set,cable_area(12),cable_area12
*set,cable_area(13),cable_area13
*set,cable_dens(1),13.2/cable_area1
*set,cable_dens(2),13.2/cable_area2
*set,cable_dens(3),20.9/cable_area3
*set,cable_dens(4),20.9/cable_area4
*set,cable_dens(5),20.9/cable_area5
*set,cable_dens(6),20.9/cable_area6
*set,cable_dens(7),24.2/cable_area7
*set,cable_dens(8),24.2/cable_area8
*set,cable_dens(9),24.2/cable_area9
*set,cable_dens(10),29.7/cable_area10
*set,cable_dens(11),29.7/cable_area11
*set,cable_dens(12),29.7/cable_area12
*set,cable_dens(13),29.7/cable_area13
*set,cable_dens_back,159.5/cable_area_back
*set,cable_istrain1,0.26032E-02
*set,cable_istrain2,0.25568E-02
*set,cable_istrain3,0.23210E-02
*set,cable_istrain4,0.23456E-02
*set,cable_istrain5,0.23892E-02
*set,cable_istrain6,0.24412E-02
*set,cable_istrain7,0.28199E-02
*set,cable_istrain8,0.28719E-02
*set,cable_istrain9,0.29143E-02
*set,cable_istrain10,0.28321E-02
*set,cable_istrain11,0.28559E-02
*set,cable_istrain12,0.28743E-02
*set,cable_istrain13,0.28926E-02
cable_back_istrain1=0.32891E-02
cable_back_istrain2=0.33661E-02
*set
,cable_istrain(1),cable_istrain1
*set,cable_istrain(2),cable_istrain2
*set,cable_istrain(3),cable_istrain3
*set,cable_istrain(4),cable_istrain4
*set,cable_istrain(5),cable_istrain5
*set,cable_istrain(6),cable_istrain6
*set,cable_istrain(7),cable_istrain7
*set,cable_istrain(8),cable_istrain8
*set,cable_istrain(9),cable_istrain9
*set,cable_istrain(10),cable_istrain10
*set,cable_istrain(11),cable_istrain11
*set,cable_istrain(12),cable_istrain12
*set,cable_istrain(13),cable_istrain13
/com,create the kps of croSSbeams
*set,w5,5.35 !横梁到主梁中心的距离
*do,i,1,13
k,kp_numfour+i*14+400+12,i*7+6,beam_height,-w5
k,kp_numfour+i*14+800+12,i*7+6,beam_height,w5
*enddo
!定义拉索单元
*do,i,1,13
et,enum_link+i-1,link10
mp,ex,enum_link+i-1,2.0e11
mp,prxy,enum_link+i-1,0.3
mp,dens,enum_link+i-1,cable_dens(i)
!mp,alpx,enum_link+i-1,1.5e-05 !定义索(钢材)的线膨胀系数
lsel,u,real,,1,1000
r,i+enum_link-1,cable_area(i),cable_istrain(i)
lstr,30-2*(i-1),kp_numfour+i*14+400+12
lstr,30-2*(i-1),kp_numfour+i*14+800+12
latt,enum_link+i-1,enum_link+i-1,enum_link+i-1
lesize,all,,,1,,1
lmesh,all
lsel,all
*enddo
/com,create the back cables
*set,enum_back_cable,enum_link+13
et,enum_back_cable,link10
mp,ex,enum_back_cable,2.0e11
mp,prxy,enum_back_cable,0.3
mp,dens,enum_back_cable,cable_dens_back
r,enum_back_cable,cable_area_back,cable_back_istrain1
lsel,u,real,,1,enum_back_cable-1
k,3001,-45,
k,3002,-45+2.956
lstr,3001,10
latt,enum_back_cable,enum_back_cable,enum_back_cable
lesize,all,,,1,,1
lmesh,all
allsel,all
et,enum_back_cable+1,link10
mp,ex,enum_back_cable+1,2.0e11
mp,prxy,enum_back_cable+1,0.3
mp,dens,enum_back_cable+1,cable_dens_back
r,enum_back_cable+1,cable_area_back,cable_back_istrain2
lsel,u,real,,1,200
lstr,3002,18
latt,enum_back_cable+1,enum_back_cable+1,enum_back_cable+1
lesize,all,,,1,,1
lmesh,all
allsel,all
esel,s,ename,,link10
cm,cable,elem
alls
/com,create the croSSbeams
*set,enum_croSSbeam,enum_back_cable+2 !横梁的单元号
et,enum_croSSbeam,beam4
mp,ex,enum_croSSbeam,3.5e20
mp,prxy,enum_croSSbeam,0.167
mp,dens,enum_croSSbeam,2500
r,enum_croSSbeam,0.5,0.5**3/12,0.5/12,0.5,1,
lsel,u,real,,1,150
*do,i,1,13
lstr,kp_numfour+i*14+400+12,kp_numfour+i*14+12
lstr,kp_numfour+i*14+12,kp_numfour+14*i+800+12
lesize,all,,,3,,1
latt,enum_croSSbeam,enum_croSSbeam,enum_croSSbeam,
lmesh,all
*enddo
allsel,all
dk,kp_numthree,all,
dk,kp_numthree+100,all,
dk,kp_numfour,all,
dk,3001,all,
dk,3002,all,
dk,kp_numfive,uy,
/solu
antype,0
acel,,10
alls
solve
fini
save