FINISH
/CLEAR,START
/PREP7
!-------------------------------------------定义压电单元及参数
!单元定义
ET,1,SOLID5
KEYOPT,1,1,3
KEYOPT,1,3,0
KEYOPT,1,5,0
!定义材料
MPTEMP,1,0
MPDE,DENS,1
MPDATA,DENS,1,,7700
MPTEMP,1,0
MPDE,PERX,1
MPDATA,PERX,1,,826
MPDE,PERY,1
MPDATA,PERY,1,,919
MPDE,PERZ,1
MPDATA,PERZ,1,,919
!!!-------------------------------------------d矩阵,球坐标系下，r方向为3方向
TBDE,PIEZ,1
TB,PIEZ,1,,,1
TBMODIF,1,1,3.56E-010
TBMODIF,1,2,0
TBMODIF,1,3,
TBMODIF,2,1,-1.48E-010
TBMODIF,2,2,0
TBMODIF,2,3,
TBMODIF,3,1,-1.48E-010
TBMODIF,3,2,0
TBMODIF,3,3,
TBMODIF,4,1,0
TBMODIF,4,2,4.32E-010
TBMODIF,4,3,
TBMODIF,5,1,0
TBMODIF,5,2,
TBMODIF,5,3,0
TBMODIF,6,1,
TBMODIF,6,2,0
TBMODIF,6,3,4.32E-010
!!!-------------------------------------------d矩阵,球左边系下，r方向为3方向
!!!-------------------------------------------e矩阵,球左边系下，r方向为3方向
TBDE,ANEL,1,,,
TB,ANEL,1,1,21,1
TBTEMP,0
TBDATA,,11.087e-12,7.509e-12,7.509e-12,0,0,0
TBDATA,,12.035e-12,7.5179e-12,0,0,0,12.035e-12
TBDATA,,0,0,0,2.1053e-12,0,0
TBDATA,,2.1053e-12,0,2.2584e-12,,,
!!!-------------------------------------------e矩阵,球左边系下，r方向为3方向
!-------------------------------------------定义压电单元及参数
!-------------------------------------------建模
!-------------------------------------------r1内径
!-------------------------------------------r2外径
r1=7e-3
r2=10e-3
!-------------------------------------------球
cyl4,,,r1,,r2,90
VROTAT,all, , , , , ,3,2,90, ,
!-------------------------------------------球
!-------------------------------------------定义球坐标系，选择材料1，并弄将压电矩阵转置到球坐标系下
CSWPLA,11,2,1,1,
TYPE,1
MAT,1
REAL,
ESYS,11
SECNUM,
!-------------------------------------------定义球坐标系，选择材料1，并弄将压电矩阵转置到球坐标系下
!-------------------------------------------设置压电球网格密度
CSYS,2 !球坐标系，X轴为r方向
p1=5 !=============压电球厚度方向单元数
LSEL,S,LOC,X,1.1*r1,0.9*r2
LESIZE,all, , ,p1, , , , ,1
LSEL,S,LOC,X,r1
LESIZE,all, , ,4*p1, , , , ,1 !=============压电球周向单元数4*p1=============
!-------------------------------------------设置压电球网格密度
VMESH,all !画网格
allsel
!-------------------------------------------1/8球体位移边界条件
ASEL,S,LOC,X,0
APLOT
NSLA,R,1
D,ALL, ,0, , , ,UX, , , , ,
ALLSEL
ASEL,S,LOC,Y,0
APLOT
NSLA,R,1
D,ALL, ,0, , , ,UY, , , , ,
ALLSEL
ASEL,S,LOC,Z,0
APLOT
NSLA,R,1
D,ALL, ,0, , , ,UZ, , , , ,
ALLSEL
!-------------------------------------------进入求解器
/SOLU
ALLSEL
ANTYPE,TRANS !指定分析类型
TRNOPT,FULL !指定瞬态分析方法
NLGEOM,OFF !
-----关闭大变形选项
TINTP,,0.25,0.5,0.5 !压电瞬态分析中，瞬态积分参数
EQSLV,SPAR !算法选择，稀疏矩阵算法
OUTPR,ALL,ALL !控制结果的输出
OUTRES,ALL,2 !保存所有的数据到结果文件中，2步输出一个结果文件
TIMINT,ON,ALL !使用瞬态效应
!-------------------------------------------施加电压1,v1=0
CSYS,2
ASEL,S,LOC,X,r1
APLOT
NSLA,R,1
*SET,V1,0
CP,1,VOLT,ALL !耦合电压
*GET,N1,NODE,,NUM,MIN
D,N1,VOLT,V1 !施加电压荷载
ALLSEL,ALL
!-------------------------------------------施加电压2
ASEL,S,LOC,X,r2
NSLA,R,1
*SET,V2,200
CP,2,VOLT,ALL !耦合电压
*GET,N2,NODE,,NUM,MIN
!D,N2,VOLT,V2 !施加电压荷载
ALLSEL,ALL
CSYS,0
!----------------------------------施正弦加电压2，并求解
f=100000 !激励电压频率
T=1/f
st=25 !每一个周期求解步数
DT=T/st
stepp=5*st !5个周期
*DO,J,1,stepp
t1=f*DT*J !5个正弦波
D,N2,VOLT,V2*SIN(2*3.1415926*t1) !施加电压荷载
TIME,DT*J !载荷时间步
NSUBST,1,,,1
SOLVE
*ENDDO
TIME,2*stepp*DT !再算5周期
NSUBST,50,,,1 !5周期，计算50步
KBC,0
SOLVE
FINISH
/POST26 !时间后处理器
NSEL,S,LOC,X,r2
NSEL,r,LOC,y,
NSEL,r,LOC,z,
*GET,N3,NODE,,NUM,MIN
NSOL,3,N3,U,X, UX_3,
PLVAR,3,